Notes

Disk info for cple_Awacs_Battle_At_Sea_Journey_To_The_Center_Of_Earth_Palace_In_Thunderland_Adams_Sampler.do:

File Name: a2_cple_Awacs_Battle_At_Sea_Journey_To_The_Center_Of_Earth_Palace_In_Thunderland_Ad/cple_Awacs_Battle_At_Sea_Journey_To_The_Center_Of_Earth_Palace_In_Thunderland_Adams_Sampler.do
Disk Name: DISK VOLUME #254
Physical Size (bytes): 143360
Free Space (bytes): 4352
Used Space (bytes): 139008
Physical Size (KB): 140
Free Space (KB): 4
Used Space (KB): 135
Archive Order: DOS
Disk Format: DOS 3.3
Total Sectors: 560
Free Sectors: 17
Used Sectors: 543
Tracks On Disk: 35
Sectors On Disk: 16

Disk directory for cple_Awacs_Battle_At_Sea_Journey_To_The_Center_Of_Earth_Palace_In_Thunderland_Adams_Sampler.do:

a2_cple_Awacs_Battle_At_Sea_Journey_To_The_Center_Of_Earth_Palace_In_Thunderland_Ad/cple_Awacs_Battle_At_Sea_Journey_To_The_Center_Of_Earth_Palace_In_Thunderland_Adams_Sampler.do DISK VOLUME #254
B 008 CAT
* B 131 PALACE IN THUNDERLAND
* B 164 AWACS
* B 081 SPECIAL SAMPLER
* A 060 JOURNEY
* A 035 BATTLE AT SEA
DOS 3.3 format; 4,352 bytes free; 139,008 bytes used.

Text found in cple_Awacs_Battle_At_Sea_Journey_To_The_Center_Of_Earth_Palace_In_Thunderland_Adams_Sampler.do/BATTLE AT SEA.bas:

10 HOME : GOTO 100
20 VTAB 24: PRINT " >>> PRESS ANY KEY TO CONTINUE <<<";
30 IF PEEK( -16384) <128 THEN 30
40 POKE -16368,0: RETURN
100 DIM G%(9,9,6),HITS(5,6),SIZ(5),S$(6),PL$(6),V(6),H(6),SS$(5),OUT(4),X(5),Y(5)
110 SS$(1) = "DESTROYER ":SS$(2) = "CRUISER ":SS$(3) = "SUBMARINE ":SS$(4) = "BATTLESHIP ":SS$(5) = "AIR.CARRIER"
120 S$(1) = "D":S$(2) = "C":S$(3) = "S":S$(4) = "B":S$(5) = "A":S$(6) = ":":S$(0) = "+"
130 SIZ(1) = 2:SIZ(2) = 3:SIZ(3) = 3:SIZ(4) = 4:SIZ(5) = 5
140 A$ = "++++++++++"
150 GOSUB 7700
160 GOSUB 1000
170 GOSUB 2000
180 HOME : VTAB 8: FLASH : PRINT SPC( 40);: PRINT " ALL HANDS TO BATTLE STATIONS!! ";: PRINT SPC( 40);: NORMAL
190 GOSUB 7600: GOSUB 7600
200 HOME
210 GOSUB 3000
220 P = 1
230 IF P = (APPLE) THEN GOSUB 5000: GOTO 250
240 GOSUB 4000
250 GOSUB 6000
260 P = P +1: IF P >NP THEN P = 1
270 IF DEAD = 0 THEN 230
280 FOR I = 0 TO DEAD -1: IF OUT(I) = P THEN P = P +1: IF P >NP THEN P = 1
290 NEXT I
300 GOTO 230
310 VTAB 22: HTAB 1: PRINT SPC( 119);: VTAB 23: HTAB 7
320 FLASH : PRINT PL$(P);" IS THE VICTOR!!!";: NORMAL
330 GOSUB 7500
340 VTAB 1: END
1000 HOME : VTAB 8
1010 PRINT TAB( 8);"B A T T L E A T S E A"
1020 VTAB 12: PRINT TAB( 13);"BY JON VOSKUIL"
1030 GOSUB 7500
1040 FOR Z = 1 TO 1000: NEXT Z
1050 HOME : VTAB 3
1060 PRINT " EACH PLAYER HAS A 10-BY-10 GRID ON": PRINT
1070 PRINT "WHICH TO PLACE FIVE SHIPS: A DESTROYER,"
1080 PRINT "A CRUISER, A SUBMARINE, A BATTLESHIP,": PRINT
1090 PRINT "AND AN AIRCRAFT CARRIER.": PRINT
1100 PRINT " PLAYERS TAKE TURNS TRYING TO BLAST": PRINT
1110 PRINT "EACH OTHER'S SHIPS OFF THE MAP. FROM": PRINT
1120 PRINT "TWO TO FIVE HITS ARE NEEDED TO SINK A": PRINT
1130 PRINT "SHIP, DEPENDING ON ITS TYPE. THE WINNER"
1140 PRINT "IS THE PLAYER WHO SURVIVES THE LONGEST."
1150 GOSUB 20
1160 HOME : VTAB 3
1170 PRINT " UP TO SIX PLAYERS MAY PARTICIPATE.": PRINT
1180 PRINT "ENTERING 'APPLE' FOR ONE NAME WILL MAKE": PRINT
1190 PRINT "ME ONE OF THE PLAYERS. PRESS 'RETURN'": PRINT
1200 PRINT "BY ITSELF WHEN THERE ARE NO MORE NAMES."
1202 PRINT : PRINT "PADDLE 0 CONTROLS YOUR AIM AND HITTING": PRINT
1204 PRINT "ANY KEY BUT 'F' OR 'G' DISPLAYS THE": PRINT
1206 PRINT "CURRENT POSITION OF THE GUNSIGHT."
1210 P = 1:APPLE = 0: PRINT : PRINT
1220 PRINT "PLAYER #";P;: INPUT ": ";PL$(P)
1230 IF PL$(P) < >"" THEN 1260
1240 IF P <3 THEN 1220
1250 P = P -1: GOTO 1310
1260 IF LEFT$(PL$(P),5) < >"APPLE" THEN 1290
1270 IF APPLE >0 THEN 1220
1280 APPLE = P
1290 IF LEN(PL$(P)) >8 THEN PL$(P) = LEFT$(PL$(P),8)
1300 IF P <6 THEN P = P +1: GOTO 1220
1310 NP = P: HOME : RETURN
2000 FOR P = 1 TO NP: HOME
2010 IF APPLE = P THEN GOSUB 2500: GOTO 2460
2020 PRINT " DES- BATTLE- AIR. TROYER CRUISER SUB SHIP CARRIER"
2030 VTAB 4: INVERSE : HTAB 3: PRINT "DD";: HTAB 12: PRINT "CCC";: HTAB 20: PRINT "SSS";: HTAB 26: PRINT "BBBB";: HTAB 35: PRINT "AAAAA";: NORMAL
2040 H = 20:V = 8: GOSUB 3500
2050 VTAB 7: HTAB 20: PRINT "ABCDEFGHIJ";
2060 FOR I = 0 TO 9: VTAB 8 +I: HTAB 19: PRINT I;: HTAB 30: PRINT I;: NEXT I
2070 VTAB 18: HTAB 20: PRINT "ABCDEFGHIJ";
2080 VTAB 21: HTAB 1: PRINT PL$(P);", IT'S YOUR TURN TO SET UP YOUR"
2090 PRINT "SHIPS. TYPE IN TWO LETTER/NUMBER PAIRS TO POSITION THE END POINTS OF EACH SHIP IN TURN. (OTHER PLAYERS, TURN AWAY!!!)";
2100 FOR Z = 1 TO 1500: NEXT Z
2110 FOR S = 1 TO 5
2120 VTAB 8: HTAB 3: PRINT SS$(S);
2130 VTAB 9: HTAB 2: PRINT "------------";
2140 VTAB 11: HTAB 3: PRINT "FROM:";
2150 VTAB 11: HTAB 9: GET X$:X1 = ASC(X$) -65
2160 IF X1 <0 OR X1 >9 THEN 2150
2170 VTAB 11: HTAB 9: PRINT X$;
2180 VTAB 11: HTAB 11: GET Y$:Y1 = ASC(Y$) -48
2190 IF Y1 = -40 THEN 2150: REM BACKSPACE
2200 IF Y1 <0 OR Y1 >9 THEN 2180
2210 VTAB 11: HTAB 11: PRINT Y$;
2220 VTAB 13: HTAB 3: PRINT "TO:";
2230 VTAB 13: HTAB 9: GET X$:X2 = ASC(X$) -65
2240 IF X2 = -57 THEN 2180
2250 IF X2 <0 OR X2 >9 THEN 2230
2260 VTAB 13: HTAB 9: PRINT X$;
2270 VTAB 13: HTAB 11: GET Y$:Y2 = ASC(Y$) -48
2280 IF Y2 = -40 THEN 2230
2290 IF Y2 <0 OR Y2 >9 THEN 2270
2300 VTAB 13: HTAB 11: PRINT Y$;
2310 VTAB 15: HTAB 1: PRINT "CORRECT? (Y/N)";: GET Z$: IF Z$ = "N" THEN 2140
2320 IF Z$ < >"Y" THEN 2310
2330 XD = X2 -X1:YD = Y2 -Y1:X = ABS(XD):Y = ABS(YD): IF X = 0 AND Y = SIZ(S) -1 THEN 2380
2340 IF Y = 0 AND X = SIZ(S) -1 THEN 2380
2350 IF Y = X AND X = SIZ(S) -1 THEN 2380
2360 VTAB 15: HTAB 1: FLASH : PRINT "> TRY AGAIN! <";: NORMAL
2370 FOR Z = 1 TO 2000: NEXT Z: VTAB 15: HTAB 1: PRINT SPC( 14): GOTO 2140
2380 IF G%(X1,Y1,P) < >0 OR G%(X2,Y2,P) < >0 THEN 2360
2390 IF SIZ(S) = 2 THEN 2420
2400 FOR I = 2 TO S -1: IF G%(X1 +(I -1) *XD/(SIZ(S) -1),Y1 +(I -1) *YD/(SIZ(S) -1),P) < >0 THEN 2360
2410 NEXT I
2420 G%(X1,Y1,P) = S:G%(X2,Y2,P) = S: VTAB Y1 +8: HTAB X1 +20: PRINT S$(S);: VTAB Y2 +8: HTAB X2 +20: PRINT S$(S);: IF SIZ(S) = 2 THEN 2440
2430 FOR I = 2 TO SIZ(S) -1:XX = X1 +(I -1) *XD/(SIZ(S) -1):YY = Y1 +(I -1) *YD/(SIZ(S) -1):G%(XX,YY,P) = S: VTAB YY +8: HTAB XX +20: PRINT S$(S);: NEXT I
2440 VTAB 11: HTAB 3: PRINT SPC( 10);: VTAB 13: HTAB 3: PRINT SPC( 10);: VTAB 15: HTAB 1: PRINT SPC( 14);
2450 NEXT S
2460 FOR Z = 1 TO 2500: NEXT Z: NEXT P
2470 RETURN
2500 HOME : VTAB 15: PRINT " APPLE IS NOW SETTING UP ITS SHIPS..."
2510 FOR S = 1 TO 5
2520 X = INT( RND(1) *10):Y = INT( RND(1) *10)
2530 XI = INT( RND(1) *3) -1:YI = INT( RND(1) *3) -1: IF XI = 0 AND YI = 0 THEN 2530
2540 FOR I = 1 TO SIZ(S):XX = X +I *XI:YY = Y +I *YI
2550 IF XX <0 OR XX >9 OR YY <0 OR YY >9 THEN 2520
2560 IF G%(XX,YY,P) >0 THEN 2520
2570 NEXT I
2580 FOR I = 1 TO SIZ(S):G%(X +XI *I,Y +YI *I,P) = S: NEXT I
2590 NEXT S
2600 FOR Z = 1 TO 1000: NEXT Z
2610 RETURN
3000 FOR I = 1 TO 4:V(I) = 1:H(I) = 2: NEXT I
3010 IF NP <4 THEN V(1) = 6:V(2) = 6:V(3) = 6: GOTO 3040
3020 V(4) = 12: IF NP = 4 THEN V(3) = 12: GOTO 3040
3030 V(5) = 12:V(6) = 12
3040 IF NP = 2 OR NP = 4 THEN H(2) = 30:H(4) = 30: GOTO 3080
3050 IF NP = 3 THEN H(2) = 16:H(3) = 30: GOTO 3080
3060 H(2) = 16:H(3) = 30: IF NP = 5 THEN H(5) = 30: GOTO 3080
3070 H(5) = 16:H(6) = 30
3080 FOR P = 1 TO NP
3090 H = H(P):V = V(P): GOSUB 3500
3100 NEXT P: RETURN
3500 INVERSE : FOR I = 0 TO 9
3510 VTAB V +I: HTAB H: PRINT A$;
3520 NEXT I
3530 NORMAL : FOR J = 1 TO LEN(PL$(P))
3540 VTAB V +J: HTAB H -1
3550 PRINT MID$ (PL$(P),J,1);
3560 NEXT J
3570 RETURN
4000 VTAB 23: HTAB 1: PRINT PL$(P);"'S TURN"
4005 IF NP = 2 THEN GOTO 4050
4010 FOR I = 1 TO 2000: NEXT I
4050 VTAB 23: HTAB 1: PRINT SPC( 79);: VTAB 22: HTAB 1
4060 IF NP >2 THEN PRINT "PRESS 'G' TO SELECT GRID."
4070 PRINT : PRINT "PRESS 'F' TO FIRE.";
4080 G = 1
4090 IF G = P THEN G = G +1: IF G >NP THEN G = 1
4100 IF DEAD = 0 THEN 4140
4110 FOR I = 0 TO DEAD -1: IF G < >OUT(I) THEN NEXT I: GOTO 4140
4120 G = G +1: IF G >NP THEN G = 1
4130 GOTO 4090
4140 HO = H(G) +5:VO = V(G) +5:OH = 5:OV = 5
4150 PN = PDL(0)/2: IF PN >99 THEN PN = 99
4160 VV = INT(PN/10):HH = PN -VV *10:V = VV +V(G):H = HH +H(G)
4170 IF H = HO AND V = VO THEN 4240
4180 INVERSE : VTAB VO: HTAB HO:S = G%(OH,OV,G): IF S > -1 THEN PRINT "+";: GOTO 4210
4190 IF S > -6 THEN NORMAL
4200 PRINT S$( ABS(S));
4210 FLASH : VTAB V: HTAB H:S = G%(HH,VV,G): IF S > -1 THEN PRINT "+";: GOTO 4230
4220 PRINT S$( ABS(S));
4230 R = RND(1) *100 +100: & TR,8
4235 IF PEEK( -16384) <127 THEN GOTO 4256
4236 POKE -16368,0
4240 VTAB 23: HTAB 20: GET Q$
4250 IF Q$ = "G" THEN GOTO 4260
4255 IF Q$ = "F" THEN GOTO 4310
4256 HO = H:VO = V:OH = HO -H(G):OV = VO -V(G): GOTO 4150
4260 VTAB V: HTAB H: INVERSE :S = G%(HH,VV,G): IF S > -1 THEN PRINT "+";: GOTO 4290
4270 IF S > -6 THEN NORMAL
4280 PRINT S$( ABS(S));
4290 G = G +1: IF G >NP THEN G = 1
4300 GOTO 4090
4310 REM FIRE SEQUENCE
4330 S = G%(HH,VV,G): IF S <0 THEN PRINT "";: GOTO 4150
4340 NORMAL : VTAB 22: HTAB 1: PRINT SPC( 119);
4350 RETURN
5000 VTAB 22: HTAB 1: PRINT "APPLE'S TURN"
5010 IF NP = 2 THEN G = 3 -APPLE: GOTO 5070
5020 LEAST = 17
5030 FOR I = 1 TO NP: IF I = (APPLE) THEN 5060
5040 HITS = 0: FOR J = 1 TO 5:HITS = HITS +HITS(J,I): NEXT J
5050 IF HITS 0 AND HITS(I,G) CHOICE THEN CHOICE = I:HITS = HITS(I,G)
5090 NEXT I
5100 IF CHOICE = 0 THEN 5270
5110 J = 1: FOR Y = 0 TO 9: FOR X = 0 TO 9: IF G%(X,Y,G) = -CHOICE THEN X(J) = X:Y(J) = Y:J = J +1
5120 NEXT X,Y: IF HITS < >1 THEN 5190
5130 MAX = 0: FOR YI = -1 TO 1: FOR XI = -1 TO 1:I = 1: IF XI = 0 AND YI = 0 THEN 5170
5140 XX = X(1) +I *XI:YY = Y(1) +I *YI: IF XX <0 OR XX >9 OR YY <0 OR YY >9 THEN 5160
5150 IF G%(XX,YY,G) > -1 THEN I = I +1: GOTO 5140
5160 IF I >MAX THEN MAX = I:XD = XI:YD = YI
5170 NEXT XI,YI
5180 X = X(1) +XD:Y = Y(1) +YD: GOTO 5330
5190 IF ABS(X(HITS) -X(1)) = HITS -1 OR ABS(Y(HITS) -Y(1)) = HITS -1 THEN 5230
5200 FOR I = 2 TO HITS:AX = ABS(X(I) -X(I -1)):AY = ABS(Y(I) -Y(I -1)): IF AX = 1 OR AY = 1 THEN NEXT I
5210 X = INT((X(I) +X(I -1))/2 +.5):Y = INT((Y(I) +Y(I -1))/2 +.5)
5220 GOTO 5330
5230 X = X(1) -(X(HITS) -X(1))/(HITS -1):Y = Y(1) -(Y(HITS) -Y(1))/(HITS -1)
5240 IF X > -1 AND X <10 AND Y > -1 AND Y <10 THEN IF G%(X,Y,G) > -1 THEN 5330
5250 X = X(HITS) +(X(HITS) -X(1))/(HITS -1):Y = Y(HITS) +(Y(HITS) -Y(1))/(HITS -1)
5260 GOTO 5330
5270 X = INT( RND(1) *10):Y = INT( RND(1) *10)
5280 IF G%(X,Y,G) <0 THEN 5270
5290 N = 0: FOR YI = -1 TO 1: FOR XI = -1 TO 1: IF XI = 0 AND YI = 0 THEN 5320
5300 XX = X +XI:YY = Y +YI: IF XX <0 OR XX >9 OR YY <0 OR YY >9 THEN 5320
5310 IF G%(XX,YY,G) > -1 THEN N = N +1
5320 NEXT XI,YI: IF N <4 THEN 5270
5330 FOR I = 1 TO RND(1) *8 +4
5335 H = RND(1) *10:V = RND(1) *10
5340 IF G%(H,V,G) <0 THEN 5335
5350 HTAB H +H(G): VTAB V +V(G): FLASH : PRINT "+";
5360 R = RND(1) *100 +100: & TR,8
5370 FOR Z = 1 TO RND(1) *500: NEXT Z
5380 HTAB H +H(G): VTAB V +V(G): INVERSE : PRINT "+";
5390 NEXT I
5400 HH = X:VV = Y:H = HH +H(G):V = VV +V(G):S = G%(HH,VV,G)
5410 HTAB H: VTAB V: FLASH : PRINT "+";
5420 R = RND(1) *100 +100: & TR,8
5430 FOR Z = 1 TO RND(1) *1000 +500: NEXT Z
5440 HO = 0:VO = 0
5450 NORMAL : RETURN
6000 GOSUB 7000
6010 VTAB 22: HTAB 1: PRINT SPC( 119);
6020 IF S >0 THEN 6120
6030 GOSUB 7200
6040 VTAB 22: HTAB 1: IF APPLE < >P THEN 6070
6050 RESTORE : FOR I = 1 TO RND(1) *10 +1: READ R$: NEXT I
6060 PRINT R$: GOTO 6080
6070 PRINT "SORRY, ";PL$(P);", YOU MISSED."
6080 G%(HH,VV,G) = -6
6090 VTAB V: HTAB H: INVERSE : PRINT ":";: NORMAL
6100 FOR Z = 1 TO 2000: NEXT Z
6110 VTAB 22: HTAB 1: PRINT SPC( 39): GOTO 6250
6120 GOSUB 7400
6130 VTAB 22: HTAB 1: PRINT "A HIT ON ";PL$(G);"'S ";SS$(S);"!"
6140 G%(HH,VV,G) = -S
6150 VTAB V: HTAB H: PRINT S$(S);
6160 HITS(S,G) = HITS(S,G) +1
6170 IF HITS(S,G) = SIZ(S) THEN VTAB 23: HTAB 1: PRINT ;SS$(S);" SUNK!!!";: GOSUB 7600
6180 HITS = 0: FOR I = 1 TO 5:HITS = HITS +HITS(I,G): NEXT I
6190 FOR Z = 1 TO 2000: NEXT Z: VTAB 22: HTAB 1: PRINT SPC( 119);
6200 IF HITS <17 THEN 6250
6210 FLASH : VTAB 22: HTAB 1: PRINT PL$(G);"'S FLEET IS DESTROYED!": NORMAL
6220 GOSUB 7500: FOR Z = 1 TO 1000: NEXT Z
6230 VTAB 22: HTAB 1: PRINT SPC( 39);
6240 OUT(DEAD) = G:DEAD = DEAD +1: IF DEAD = NP -1 THEN POP : GOTO 310
6250 RETURN
6260 DATA "RATS, MISSED AGAIN.","I THOUGHT I HAD YOU THAT TIME!","I WAS SURE I SAW A BLIP ON RADAR. . .","JUST WAIT TILL NEXT TIME.","THE BATTLE ISN'T OVER YET!!"
6270 DATA "I'LL BET THAT WAS CLOSE, THOUGH!","I HOPE YOU'RE A GOOD SWIMMER.","THAT WAS JUST TO GET YOUR ATTENTION.","ONE LESS PLACE TO HIDE...","NEXT TIME I'M GONNA AIM..."
7000 N = 5:TM = 10
7010 FOR I = 1 TO 255 STEP N: & TI,TM: NEXT
7020 RETURN
7200 P1 = 200 + RND(1) *56:P2 = 80 + RND(1) *50:T1 = 10 + RND(1) *6:T2 = 18 + RND(1) *6
7210 FOR Z = 1 TO 500: NEXT Z
7220 & TP1,T1: & TP2,T2
7230 RETURN
7400 POKE -16302,0
7410 R1 = 200 + RND(1) *55:R2 = 3 + RND(1) *3:R3 = 18 + RND(1) *7:R4 = 3 + RND(1) *3
7420 FOR J = 1 TO 4 + RND(1) *3: FOR I = 1 TO 8 + RND(1) *3: POKE -16304,0
7430 & TR1/I,R2: & TR3 *I,R4
7440 POKE -16303,0: NEXT : NEXT
7450 RETURN
7500 & T192,200: & T153,100: & T128,100: & T114,150: & T153,50: & T114,200: & T96,200: & T86,100: & T128,100: & T96,250
7510 RETURN
7600 FOR J = 1 TO 3
7610 FOR I = 1 TO 30: & T255,3: NEXT I
7620 FOR I = 1 TO 30: & T150,8: NEXT I
7630 FOR I = 1 TO 20: & T255,3: NEXT I
7640 FOR I = 1 TO 300: NEXT I
7650 NEXT J
7660 RETURN
7700 POK$ = "201,084,208,015,032,177,000,032,248,230,138,072,032,183,000,201,044,240,003,076,201,222,032,177,000,032,248,230,104,134,003,134,001,133,000"
7710 FOR I = 1 TO 35: POKE I +767, VAL( MID$ (POK$,I *4 -3,I *4 -1)): NEXT I
7720 POK$ = "170,160,001,132,002,173,048,192,136,208,004,198,001,240,007,202,208,246,166,000,208,239,165,003,133,001,198,002,208,241,096"
7730 FOR I = 1 TO 33: POKE I +802, VAL( MID$ (POK$,I *4 -3,I *4 -1)): NEXT I
7740 POKE 1013,76: POKE 1014,0: POKE 1015,3
7750 RETURN
7760 POK$ = "201,084,208,015,032,177,000,032,248,230,138,072,032,183,000,201,L044,240,003,076,302,222,032,177,000,032,248,230,104,234,003,L134,L001,133,000"

Text found in cple_Awacs_Battle_At_Sea_Journey_To_The_Center_Of_Earth_Palace_In_Thunderland_Adams_Sampler.do/JOURNEY.bas:

10 CLEAR
20 IF NA$ < >"" THEN 50
30 HOME : INPUT "WHAT IS YOUR NAME ?";NA$
40 NA$ = NA$ +"/JOURNEY"
50 HOME
60 PRINT TAB( 9)"JOURNEY TO THE CENTER"
70 PRINT TAB( 14)"OF THE EARTH": PRINT
80 PRINT TAB( 12)"BY GREG HASSETT"
90 CP = 1: GOSUB 2010
100 HOME
110 GOSUB 1910: GOSUB 1800
120 IF CP = 18 AND (VB < >25 OR NO < >21) THEN PRINT "HORRORS! THE TROLL THROWS AN AXE AT ME! I AM DEAD.": GOTO 1510
130 IF CP = 18 THEN PRINT M2$:F5 = 1: GOSUB 1800
140 IF NO <23 OR VB >1 OR NO >30 THEN 230
150 IF NO < = 26 THEN FD = FD +1: GOTO 160
155 FD = -10000
160 IF NO >26 THEN NO = NO -4
170 NO = NO -22
180 IF CP = 10 AND NO = 1 THEN PRINT "AND FALL INTO THE LAVA??? FAT CHANCE!": GOSUB 1800: GOTO 140
190 IF CP = 11 AND NO = 2 THEN PRINT "DO YOU KNOW WHAT LAVA IS??? IT'S HOT, THAT'S WHAT!": GOSUB 1800: GOTO 140
200 IF CP = 29 AND OB(10,0) = 29 AND (NO = 4 OR NO = 2) THEN PRINT "THE HYDRA WON'T LET ME THROUGH!": GOSUB 1800: GOTO 140
210 IF P(CP,NO) = 0 THEN PRINT "I CAN'T GO THAT WAY!": GOSUB 1800: GOTO 140
220 CP = P(CP,NO): GOTO 100
230 IF VB < >2 AND VB < >20 THEN 310
240 IF NO = 10 AND OB(33,0) = CP THEN PRINT "IT IS SORT OF HEAVY, YOU KNOW.": GOSUB 1800: GOTO 140
250 IF NO = 0 THEN PRINT "I DON'T KNOW WHAT A '"NO$"' IS.": GOSUB 1800: GOTO 140
260 IF OB(NO,0) < >CP THEN PRINT "I DON'T SEE IT HERE.": GOSUB 1800: GOTO 140
270 IF NO = 10 OR NO = 20 THEN PRINT "OH GIVE ME A BREAK!!": GOSUB 1800: GOTO 140
280 IF OB(NO,0) = -1 THEN PRINT "I'M ALREADY CARRYING IT.": GOSUB 1800: GOTO 140
290 IF OB(NO,0) = CP AND NT > = 6 THEN PRINT "I CAN'T CARRY ANY MORE. YOU'LL HAVE TO DROP SOMETHING.": GOSUB 1800: GOTO 140
300 IF OB(NO,0) = CP THEN PRINT "CHECK.":NT = NT +1:OB(NO,0) = -1: GOSUB 1800: GOTO 140
310 IF VB < >4 AND VB < >29 THEN 360
320 F3 = 0
330 PRINT "I AM CURRENTLY CARRYING :": FOR I = 1 TO LO: IF OB(I,0) = -1 THEN PRINT OB$(I):F3 = 1
340 NEXT I: IF F3 = 0 THEN PRINT "NOTHING."
350 GOSUB 1800: GOTO 140
360 IF VB = 3 THEN 100
370 IF NO = 0 AND VB = 0 THEN PRINT "THAT DOESN'T MAKE ANY SENSE TO ME.": GOSUB 1800: GOTO 140
380 IF VB < >5 THEN 440
390 J = 0
400 FOR I = 1 TO LO: IF OB(I,0) = 1 THEN J = J +OB(I,1)
410 NEXT I: PRINT "OUT OF A MAXIMUM OF 175 POINTS, YOU HAVE "J"."
420 IF J = 0 THEN PRINT "BOY, YOU STINK!"
430 GOSUB 1800: GOTO 140
440 IF VB < >6 AND VB < >22 THEN 510
450 IF NO$ < >"EVERYTHING" AND NO$ < >"ALL" THEN 490
460 FOR I = 1 TO LO: IF OB(I,0) = -1 THEN OB(I,0) = CP
470 NEXT I:NT = 0
480 PRINT "OKAY.": GOSUB 1800: GOTO 140
490 IF OB(NO,0) < > -1 THEN PRINT "HOW CAN I DROP WHAT I'M NOT HOLDING???": GOSUB 1800: GOTO 140
500 OB(NO,0) = CP: PRINT "O.K.":NT = NT -1: GOSUB 1800: GOTO 140
510 IF VB < >7 AND VB < >28 THEN 550
520 IF H$(CP) = "" THEN PRINT "YOU GOT ME INTO THIS MESS, NOW GET ME OUT!"
530 PRINT H$(CP):H$(CP) = ""
540 GOSUB 1800: GOTO 140
550 IF VB < >8 THEN 640
560 HOME : INPUT "SAVE TO CASSETTE OR DISK ?";IO$:IO$ = LEFT$(IO$,1): IF IO$ < >"C" AND IO$ < >"D" THEN 560
561 IF IO$ = "C" THEN 570
562 PRINT "PRESS WHEN DISK": INPUT "PREPARATIONS ARE MADE.";XX$: PRINT "SAVING."
563 PRINT "OPEN"NA$
564 FOR I = 1 TO LO: PRINT "WRITE"NA$: IF OB$(I) = "" THEN 566
565 PRINT OB(I,0): PRINT OB(I,1)
566 NEXT I: PRINT CP
567 PRINT "CLOSE"NA$
568 GOTO 630
570 PRINT "PRESS WHEN CASSETTE": INPUT "PREPARATIONS ARE MADE.";XX$: PRINT "SAVING."
571 FOR I = 1 TO LO: IF OB$(I) = "" THEN 574
572 XX(I,0) = OB(I,0)
573 XX(I,1) = OB(I,1)
574 NEXT I
575 XX(LO +1,0) = CP
576 STORE XX
630 GOSUB 1800: GOTO 140
640 IF VB < >9 THEN 720
650 HOME : INPUT "LOAD FROM CASSETTE OR DISK ?";IO$:IO$ = LEFT$(IO$,1): IF IO$ < >"C" AND IO$ < >"D" THEN 650
660 IF IO$ = "C" THEN 670
661 PRINT "PRESS WHEN DISK": INPUT "PREPARATIONS ARE MADE.";XX$: PRINT "LOADING.": PRINT "OPEN"NA$
662 FOR I = 1 TO LO: PRINT "READ"NA$: IF OB$(I) = "" THEN 664
663 INPUT OB(I,0),OB(I,1)
664 NEXT I: INPUT CP
665 PRINT "CLOSE"NA$: GOTO 710
670 PRINT "PRESS WHEN CASSETTE": INPUT "PREPARATIONS ARE MADE.";XX$: PRINT "LOADING.": RECALL XX
671 FOR I = 1 TO LO: IF OB$(I) = "" THEN 674
672 OB(I,0) = XX(I,0)
673 OB(I,1) = XX(I,1)
674 NEXT I:CP = XX(LO +1,0)
710 GOTO 100
720 IF VB < >10 THEN 740
730 GOTO 1520
740 IF VB < >11 THEN 770
750 IF NO = 0 THEN PRINT "SAY WHAT?": GOSUB 1800: GOTO 140
760 PRINT "OKAY. IF IT IS REALLY NECESSARY...": GOSUB 1800: GOTO 140
770 IF VB < >12 THEN 810
780 IF NO < >12 THEN PRINT "I DON'T DO STUPID THINGS.": GOSUB 1800: GOTO 140
790 IF OB(12,0) < > -1 THEN PRINT "I DON'T HAVE ANY COKE TO DRINK!": GOSUB 1800: GOTO 140
800 PRINT M3$:OB(12,0) = 0:OB(13,0) = -1: GOSUB 1800: GOTO 140
810 IF VB < >13 THEN 880
820 IF OB(31,0) < > -1 THEN PRINT "BUT I HAVE NO FOOD!!": GOSUB 1800: GOTO 140
830 IF OB(NO,0) < >CP THEN PRINT "I DON'T SEE IT.": GOSUB 1800: GOTO 140
840 IF NO = 10 THEN PRINT "THE HYDRA WHARFS DOWN THE FOOD.":OB(31,0) = 0:OB$(10) = "A GIANT HYDRA RUBBING HIS STOMACH": GOSUB 1800: GOTO 140
850 IF NO = 20 THEN PRINT "THE BUGS IN THESE CAVES ONLY EAT HUMAN FLESH.": GOSUB 1800: GOTO 140
860 IF NO < >3 THEN PRINT "YOU CAN'T BE SERIOUS.": GOSUB 1800: GOTO 140
870 PRINT "IT REFUSES TO EAT THE FOOD.": GOSUB 1800: GOTO 140
880 IF VB < >14 THEN 960
890 IF NO = 10 AND OB(33,0) = CP THEN PRINT "THE UNDERTAKER JUST TOOK HIM AWAY.":OB(33,0) = 0: GOSUB 1800: GOTO 140
900 IF OB(NO,0) < >CP AND OB(NO,0) < > -1 THEN PRINT "I DON'T SEE IT AND I'M NOT HOLDING IT, SO HOW CAN I HIT IT?": GOSUB 1800: GOTO 140
910 IF NO = 3 THEN PRINT "NO!!! I KIND OF LIKE THE PARROT! POLLY WANT A CRACKER?"
920 IF NO = 10 THEN PRINT "OKAY... THE HYDRA GRUNTS >>DAMN MOSQUITOS<<"
930 IF NO = 20 THEN PRINT "YUCH! I DON'T WANT TO TOUCH!!!"
940 IF NO = 3 OR NO = 10 OR NO = 20 THEN GOSUB 1800: GOTO 140
950 PRINT "OKAY... OUCH! I HURT MY HAND!": GOSUB 1800: GOTO 140
960 IF VB = 15 THEN PRINT "I CAN'T KILL ANYTHING, I'M TOO WEAK. BUT MAYBE IF YOU WERE MORE SPECIFIC...": GOSUB 1800: GOTO 140
970 IF VB < >16 THEN 1060
980 IF OB(33,0) = CP AND NO = 10 THEN PRINT "IT IS ALREADY BURNT TO A CRISP.": GOSUB 1800: GOTO 140
990 IF OB(6,0) < > -1 THEN PRINT "I DON'T HAVE A LIGHTER OR MATCHES!!": GOSUB 1800: GOTO 140
1000 IF NO = 3 THEN PRINT "NEVER!! YOU KNOW SOMETHING, YOU'RE A SADIST.": GOSUB 1800: GOTO 140
1010 IF NO = 10 AND OB(10,0) = CP THEN OB(10,0) = 0:OB(33,0) = CP: PRINT "THE HYDRA CRUMBLES TO THE GROUND DEAD.": GOSUB 1800: GOTO 140
1020 IF NO = 20 THEN PRINT "THE BUG CANNOT BE BURNED. ": GOSUB 1800: GOTO 140
1030 IF NO = 10 THEN OB(10,0) = 0
1040 PRINT "IT DOESN'T BURN."
1050 GOSUB 1800: GOTO 140
1060 IF VB = 17 THEN PRINT "AND JUST WHO DO YOU THINK I AM, ROCKY??": GOSUB 1800: GOTO 140
1070 IF VB = 18 THEN PRINT "I DON'T KNOW HOW TO LIGHT THINGS. IF YOU WANT ME TO BURN SOMETHING, TELL ME SO!": GOSUB 1800: GOTO 140
1080 IF VB < >19 THEN 1170
1090 IF NO$ = "COIN" THEN NO$ = "QUARTER":NO = 7
1100 IF NO = 0 THEN PRINT "I DON'T KNOW WHAT ONE IS.": GOSUB 1800: GOTO 140
1110 IF NO = 7 THEN 1130
1120 IF OB(NO,0) < > -1 THEN PRINT "I'M NOT HOLDING IT RIGHT NOW.": GOSUB 1800: GOTO 140
1130 IF CP < >27 THEN PRINT "I DON'T SEE ANY COKE MACHINES HERE.": GOSUB 1800: GOTO 140
1140 IF NO < >7 THEN PRINT "THAT IS RIDICULOUS.": GOSUB 1800: GOTO 140
1150 IF OB(NO,0) < > -1 THEN PRINT "I HAVE NO MONEY.": GOSUB 1800: GOTO 140
1160 IF OB(7,0) = -1 AND CP = 27 THEN PRINT "ALL RIGHT. CHICKLIK CHINGGGG! A COKE POPPED OUT. THERE IS NOW A BOTTLE OF COKE HERE.":OB(7,0) = 0:NT = NT -1:OB(12,0) = 27: GOSUB 1800: GOTO 140
1170 REM
1180 IF VB < >21 THEN 1260
1190 IF NO < >18 AND OB(NO,0) = -1 THEN PRINT "IT'S KIND OF HEAVY, YOU KNOW.": GOSUB 1800: GOTO 140
1200 IF OB(NO,0) < > -1 THEN PRINT "FIRST YOU HAVE TO HELP ME FIND IT, DUMMY!": GOSUB 1800: GOTO 140
1210 IF CP = 10 OR CP = 11 THEN 1230
1220 PRINT "NOTHING HAPPENED.": GOSUB 1800: GOTO 140
1230 IF CP = 10 THEN CP = 11: GOTO 1250
1240 CP = 10
1250 GOTO 100
1260 IF VB = 23 THEN VB = 1: GOTO 140
1270 IF VB = 24 THEN PRINT "TRY 'KILL "NO$"'.": GOSUB 1800: GOTO 140
1280 IF VB < >25 THEN 1310
1290 IF NO = 21 THEN PRINT "NOTHING HAPPENED.": GOSUB 1800: GOTO 140
1300 PRINT "SIR WHAT??? I DON'T UNDERSTAND!": GOSUB 1800: GOTO 140
1310 IF VB < >26 THEN 1380
1320 IF CP = 1 AND OB(14,0) = -1 AND OB(22,0) = 1 THEN PRINT "OKAY!!!": GOTO 1510
1330 IF CP < >1 THEN PRINT "I CAN'T.": GOSUB 1800: GOTO 140
1340 IF VB < >26 THEN 1380
1350 IF OB(14,0) < > -1 THEN PRINT "I CAN'T. I HAVE NO TOOLS.": GOSUB 1800: GOTO 140
1360 PRINT "I CAN'T. I DON'T SEE THE FRIBULATING GONKULATOR AROUND ME.": IF OB(22,0) = -1 THEN PRINT "I THINK I HAVE TO DROP IT FIRST."
1370 GOSUB 1800: GOTO 140
1380 IF VB < >27 THEN 1460
1390 IF NO = 0 THEN PRINT "WHAT THE DEVIL IS A "NO$"??": GOSUB 1800: GOTO 140
1400 IF NO = 20 OR NO = 10 THEN IF OB(NO,0) = CP THEN PRINT "YUCH!!! I'D NEVER EAT A "NO$"!!!": GOSUB 1800: GOTO 140
1410 IF NO = 10 AND OB(33,0) = CP THEN PRINT "WELL...IT'S COOKED NOW, BUT IT STILL LOOKS RATHER GROSS.": GOSUB 1800: GOTO 140
1420 IF OB(NO,0) < > -1 THEN PRINT "I'M NOT HOLDING IT.": GOSUB 1800: GOTO 140
1430 IF NO = 3 AND OB(3,0) = -1 THEN PRINT "I'D RATHER NOT. I DON'T CARE FOR PARROT MEAT.": GOSUB 1800: GOTO 140
1440 IF NO = 31 AND OB(31,0) = -1 THEN NT = NT -1: PRINT "MMMM! IT WAS FILET MIGNON, MY FAVORITE DISH.":OB(31,0) = 0: GOSUB 1800: GOTO 140
1450 PRINT "I THINK THAT "OB$(NO)" WOULD GIVE": PRINT "ME INDIGESTION, AND I DON'T HAVE ANY PEPTO-BISMOL.": GOSUB 1800: GOTO 140
1460 IF VB < >30 THEN 1500
1470 IF CP < >10 AND CP < >11 THEN PRINT "NOTHING HAPPENED.": GOSUB 1800: GOTO 140
1480 PRINT "NICE TRY, BUT THAT'S AN OLD, WORN OUT MAGIC WORD."
1490 GOSUB 1800: GOTO 140
1500 PRINT "I DON'T KNOW HOW TO DO THAT.": GOSUB 1800: GOTO 140
1510 FOR I = 1 TO 1000: NEXT I
1520 PRINT "OUT OF A MAXIMUM OF 175 POINTS, YOU HAVESCORED ";:J = 0
1530 FOR I = 1 TO LO: IF OB(I,0) = 1 THEN J = J +OB(I,1)
1540 NEXT I
1550 PRINT J" POINTS."
1560 IF J = 175 THEN PRINT "ALL OF ADVENTUREDOM PAYS TRIBUTE TO YOU,ADVENTURER GRANDMASTER!": GOTO 1640
1570 IF J >165 THEN PRINT "YOUR SCORE PUTS YOU IN MASTER ADVENTURERCLASS 'A'.": GOTO 1640
1580 IF J >150 THEN PRINT "YOUR SCORE PUTS YOU IN MASTER ADVENTURERCLASS 'B'.": GOTO 1640
1590 IF J >140 THEN PRINT "YOU HAVE REACHED A 'JUNIOR MASTER' STATUS.": GOTO 1640
1600 IF J >120 THEN PRINT "YOU MAY NOW CONSIDER YOURSELF A 'SEASONED ADVENTURER'.": GOTO 1640
1610 IF J >110 THEN PRINT "YOU HAVE ACHIEVED THE RATING: 'EXPERIENCED ADVENTURER'.": GOTO 1640
1620 IF J >100 THEN PRINT "YOUR SCORE QUALIFIES YOU AS A 'NOVICE CLASS' ADVENTURER.": GOTO 1640
1630 PRINT "YOU ARE OBVIOUSLY A RANK AMATEUR. BETTER LUCK NEXT TIME."
1640 PRINT : INPUT "DO YOU WISH TO TRY THIS ADVENTURE AGAIN?";AG$:AG$ = LEFT$(AG$,1): IF AG$ = "N" THEN PRINT "";"CATALOG": END
1645 IF AG$ < >"Y" THEN 1520
1650 FOR K = 1 TO LEN(NA$): POKE 24576 +K, ASC( MID$ (NA$,K,1)): NEXT K: POKE 24576 +K,191
1660 CLEAR :CO = 0:NA$ = ""
1670 CO = CO +1:PE = PEEK(24576 +CO): IF PE < >191 THEN NA$ = NA$ + CHR$(PE): GOTO 1670
1680 GOTO 20
1690 PRINT "GADZOOKS!!! A GIANT BUG JUST WALKED IN TO KILL ME!!!"
1700 FF = 1
1710 GOSUB 1800
1720 IF NO$ = "SESAME" AND VB$ = "OPEN" THEN PRINT "THE BUG HAS SHRUNKEN TO ITS PROPER SIZE AND SCURRIED AWAY.": GOTO 1780
1730 IF NO < >20 OR VB < >15 THEN PRINT "HELP ME!!! I'M BEING DEVOURED BY A GIANTBUG!!! THE END IS NEAR! OW!! THIS HURTS!I'M DYING...DYING...DEAD.": GOTO 1510
1740 IF OB(2,0) < > -1 THEN NO = 2: PRINT "I DON'T HAVE A SWORD!!!": GOTO 1730
1750 IF SW = 8 THEN PRINT "MY SWORD IS DULL, REMEMBER???":NO = 2: GOTO 1730
1760 PRINT "DING! DONG! THE BUG IS DEAD! THE BUG IS DEAD!!"
1770 SW = SW +1: IF SW = 8 THEN PRINT "MY SWORD IS DULL NOW."
1780 GOSUB 1800: GOTO 140
1790 END
1800 PRINT : PRINT "ENTER YOUR COMMAND -->";:CM$ = ""
1801 GET GT$: IF ASC(GT$) = 13 THEN 1809
1802 IF ASC(GT$) < >8 THEN 1807
1803 IF LEN(CM$) < = 1 THEN CM$ = "": GOTO 1808
1804 CM$ = LEFT$(CM$, LEN(CM$) -1): GOTO 1808
1807 CM$ = CM$ +GT$
1808 PRINT GT$;: GOTO 1801
1809 PRINT
1810 IF CM$ = "ABRA CADABRA" AND F5 <3 AND FF = 1 THEN NO$ = "SESAME":VB$ = "OPEN":FF = 0:F5 = F5 +1: RETURN
1820 VB$ = "":NO$ = "":VB = 0:NO = 0
1830 LC = LEN(CM$): FOR I = 1 TO LC: IF MID$ (CM$,I,1) < >" " THEN VB$ = VB$ + MID$ (CM$,I,1): NEXT I
1840 FOR I = 1 TO NV: IF VB$(I) = VB$ THEN VB = I: GOTO 1860
1845 NEXT I
1850 VB = 0:NO$ = VB$: GOTO 1880
1860 IF LEN(VB$) +1 > LEN(CM$) THEN NO = 0: RETURN
1870 NO$ = RIGHT$(CM$, LEN(CM$) -1 - LEN(VB$))
1880 FOR I = 1 TO NN: IF NO$(I) = NO$ THEN 1900
1885 NEXT I
1890 NO = 0: RETURN
1900 NO = I: RETURN
1910 PRINT P$(CP): PRINT
1920 FOR I = 1 TO LO: IF OB(I,0) = CP THEN PRINT "THERE IS "OB$(I)" HERE."
1930 NEXT I
1940 PRINT "I CAN GO : ";:F2 = 0
1950 FOR I = 1 TO 4: IF P(CP,I) < >0 THEN PRINT NO$(I +22)" ";:F2 = 1
1960 NEXT I: IF F2 = 0 THEN PRINT "NOWHERE!": GOTO 1970
1965 PRINT
1970 IF CP = 18 AND OB(3,0) = -1 THEN PRINT : PRINT M1$
1980 IF INT( RND(1) *35) = 5 AND CP < >1 AND CP < >37 AND CP < >27 THEN PRINT : GOTO 1690
1990 IF FD >4 THEN PRINT : PRINT "IF YOU'D LIKE, YOU CAN MAKE IT EASIER ONYOURSELF BY TYPING N, S, E, OR W INSTEAD OF NORTH, SOUTH, ETC.":FD = 0
2000 RETURN
2010 NP = 37: DIM P$(NP)
2030 P$(1) = "I'M ON A SHIP. A COMPUTER SCREEN HERE SAYS: 'SHIP WILL NOT FUNCTION, FRIBULATING GONKULATOR IS BURNED OUT.' IT'S OBVIOUS THAT THE SHIP HAS CRASHED."
2040 DATA 2,6,5,4:P$(2) = "I'M IN A COBBLESTONE HALLWAY. I CAN HEARCHIRPING NEARBY, SOUNDS LIKE BUGS...": DATA 8,1,3,5
2050 P$(3) = "I'M IN A DARK ROOM...OH NO!!! THERE ARE GIANT BUGS ALL AROUND ME!!!": DATA 0,0,0,2
2060 P$(4) = "I'M IN A SMALL ROOM. A SCRIBBLING HERE SAYS: 'HAR HAR HAR! YOU'LL NEVER MAKE IT! >> ARBADAC ARBA <<'": DATA 7,0,1,0
2070 P$(5) = "I'M IN A DUSTY COBBLESTONE HALLWAY.": DATA 0,25,2,1
2080 P$(6) = "I'M IN A DUSTY PLACE. IT IS VERY DARK INHERE. I'M SCARED!": DATA 1,24,0,0
2090 P$(7) = "I'M IN A LOW CRAWL SPACE. IT SEEMS AS IFWE'RE NOT SUPPOSED TO BE HERE...": DATA 0,4,15,0
2100 P$(8) = "I'M IN A ROOM WITH ROCK WALLS. IMBEDDED IN THE WALLS ARE SCATTERED RUBIES.": DATA 9,2,0,13
2110 P$(9) = "I'M IN A DARK ROOM. THIS ONE IS NOT SO SCARY. I THINK I HEAR GRUNTS AND GROANS NEARBY.": DATA 10,8,23,0
2120 P$(10) = "I'M ON THE SOUTH SIDE OF A CHASM. MOLTENLAVA IS BENEATH ME.": DATA 11,9,0,0
2130 P$(11) = "I'M ON THE NORTH SIDE OF THE CHASM.": DATA 16,10,0,0
2140 P$(12) = "I'M IN A MAZE OF TWISTY PASSAGES.": DATA 12,12,13,14
2150 P$(13) = P$(12): DATA 13,13,8,12
2160 P$(14) = P$(12): DATA 14,15,12,14
2170 P$(15) = P$(12): DATA 14,15,15,7
2180 P$(16) = "I'M ON A WOOD PLATFORM. A SIGN WARNS: 'GO BACK! GO SOUTH!!' THERE IS A RICKEDYBRIDGE TO THE NORTH.": DATA 17,11,0,0
2190 P$(17) = "I'M IN A DUSTY PASSAGE. A SIGN POINTS EAST AND SAYS: 'TO TROLLS PLACE -->' A RICKEDY BRIDGE EXTENDS SOUTHWARD. MARKINGS IN THE DUST INDICATE THAT SOMEONE WAS HERE RECENTLY.": DATA 0,16,18,0
2200 P$(18) = "A VOICE BOOMS OUT: 'WHO DARES TO ENTER MY PALACE???' (SOUNDS LIKE A TROLL TO ME!)": DATA 0,0,19,0
2210 P$(19) = "I'M IN THE TROLL'S PALACE. IT'S BREATH- TAKING!! THE CEILING IS SO HIGH, I CAN'TEVEN SEE IT!": DATA 0,20,0,0
2220 P$(20) = "I'M AT ONE END OF A SECRET PASSAGE.": DATA 0,0,0,21
2230 P$(21) = "I'M IN A SECRET PASSAGE.": DATA 21,22,20,21
2240 P$(22) = P$(21): DATA 21,22,22,23
2250 P$(23) = P$(21): DATA 23,23,22,9
2260 P$(24) = "I'M IN A HUGE ICE CAVERN. THE CEILING AND WALLS ARE COMPLETELY ICE.": DATA 6,26,25,0
2270 P$(25) = "I'M IN A ROOM WITH MANY ANIMALS... WAIT! THEY'VE ALL RUN AWAY.": DATA 5,0,0,0
2280 P$(26) = "I AM IN A ROOM WITH TRACES OF SLIME ON THE FLOORS AND WALLS.": DATA 24,29,27,28
2290 P$(27) = "I'M IN...AL'S DINER?!? THERE'S A COKE MACHINE HERE. IT SAYS: 'ENJOY COCA-COLA.25 CENTS (NO CANADIAN COINS PLEASE)'.": DATA 0,0,0,26
2300 P$(28) = "I'M IN A HUGE PIT.": DATA 0,0,26,0
2320 P$(29) = "I'M IN THE HYDRA ROOM. THE WALLS ARE ALLSLIME. BOY, I'VE NEVER SEEN ANYTHING SO GROSS IN MY LIFE!": DATA 26,30,31,32
2330 P$(30) = "I'M IN THE DRAGON ROOM. IT SEEMS TO BE DECORATED WITH DRAGONS.": DATA 29,34,0,33
2340 P$(31) = "I'M IN A TORTURE CHAMBER. LET'S GET OUT OF HERE QUICK!!": DATA 31,31,31,29
2350 P$(32) = "THIS IS THE CLAM ROOM. THE WALLS ARE SOLID CLAMSHELL EMBEDDED IN LIMESTONE.": DATA 0,0,29,0
2360 P$(33) = "I'M IN A MAMMOTH GARDEN FULL OF PLANTS.": DATA 0,0,30,0
2370 P$(34) = "I'M IN THE VELVET ROOM. THE WALLS AND CEILING ARE VELVET.": DATA 30,34,35,0
2380 P$(35) = "I'M IN AN ARABIAN ROOM WITH GUITARS PLAYING NEARBY. THERE IS AN OIL SLICK HERE. LOOKS LIKE MACHINE OIL, 10-W-30.": DATA 36,37,0,34
2390 P$(36) = "I'M IN THE TREASURE ROOM. MANY DWARVES GUARD SOME PETTY TREASURE. NOTHING TO FLIP OVER, ANYWAY.": DATA 0,35,0,0
2400 P$(37) = "I'M AT MAC'S EARTH-DIGGER BODY SHOP.": DATA 35,0,0,0
2410 DIM P(37,4): FOR I = 1 TO 37: FOR J = 1 TO 4: READ P(I,J): NEXT J,I
2420 LO = 33: DIM OB$(LO),OB(LO,1)
2425 DIM XX(LO,1)
2430 OB$(1) = "A SET OF KEYS": DATA 6,0:OB$(2) = "A SHINY SWORD": DATA 16,0
2440 OB$(3) = "A PARROT IN A CAGE": DATA 25,5:OB$(4) = "A GOLD NUGGET": DATA 4,10
2450 OB$(5) = "A 35,000 KARAT DIAMOND": DATA 7,10:OB$(6) = "A CIGARETTE LIGHTER": DATA 28,0
2460 OB$(7) = "A QUARTER": DATA 28,0:OB$(8) = "AN ENORMOUS EMERALD": DATA 32,15
2470 OB$(9) = "SOME SILVER BARS": DATA 33,15:OB$(10) = "A GIANT HYDRA": DATA 29,0
2480 OB$(11) = "A MING VASE": DATA 30,10:OB$(12) = "A BOTTLE OF COKE": DATA 0,0
2490 OB$(13) = "AN EMPTY COKE BOTTLE": DATA 0,0:OB$(14) = "SOME TOOLS": DATA 34,0
2500 OB$(15) = "A LARGE RUBY": DATA 8,15:OB$(16) = "SOME GOLD BARS": DATA 19,20
2510 OB$(17) = "A DIAMOND NECKLACE": DATA 19,25:OB$(18) = "A MAGIC WAND": DATA 14,0
2520 OB$(22) = "A FRIBULATING GONKULATOR": DATA 37,50
2530 OB$(20) = "A GIANT BUG, ASLEEP": DATA 31,0
2540 OB$(31) = "SOME TASTY FOOD":OB$(32) = "SOME HUMAN SKELETONS":OB(32,0) = 31:OB(32,1) = 0
2550 OB$(33) = "A DEAD HYDRA ON THE GROUND"
2560 FOR I = 1 TO 20: READ OB(I,0),OB(I,1): NEXT I
2570 OB(22,0) = OB(19,0):OB(22,1) = OB(19,1)
2580 OB(19,1) = 0:OB(19,0) = 0
2590 OB(31,0) = 27:OB(31,1) = 0
2600 DATA KEYS,SWORD,PARROT,NUGGET,DIAMOND,LIGHTER,QUARTER,EMERALD,SILVER,HYDRA,VASE,COKE,BOTTLE,TOOLS,RUBY,GOLD,NECKLACE,WAND,SIGN,BUG,ALEXANDER,GONKULATOR,NORTH,SOUTH,EAST,WEST
2610 DATA N,S,E,W,FOOD,SKELETONS
2620 NN = 32: DIM NO$(NN)
2630 FOR I = 1 TO NN: READ NO$(I): NEXT I
2640 DATA GO,GET,LOOK,INVEN,SCORE,DROP,HELP,SAVE,LOAD,QUIT,SAY,DRINK,FEED,HIT,KILL,BURN,FIGHT,LIGHT,INSERT,TAKE,WAVE,RELEASE,CONTINUE,DESTROY,SIR,FIX,EAT,?,INVENTORY,HOCUS
2650 NV = 30: DIM VB$(NV): FOR I = 1 TO NV: READ VB$(I): NEXT I
2660 M1$ = "THE PARROT CHANTS: 'SIR ALEXANDER...SIR ALEXANDER!'"
2670 M2$ = "THE TROLL SCURRIES AWAY IN FEAR."
2680 M3$ = "GULP GULP GULP! (BURP) - THAT WAS REFRESHING!"
2690 DIM H$(NP)
2700 H$(25) = "THIS PARROT TALKS..."
2710 H$(29) = "CIGAR? CIGARETTE? TIPPARILLO?"
2720 H$(10) = "YOU KNOW, THIS WORLD IS ENCHANTED..."
2730 H$(12) = "YOU CAN MAKE THE PASSAGES LOOK LESS ALIKE BY DROPPING THINGS."
2740 H$(13) = H$(12):H$(14) = H$(12):H$(15) = H$(12)
2750 H$(1) = "I THINK WE'RE SUPPOSED TO LEAVE WHAT WE FIND HERE."
2760 H$(35) = "OFTEN TIMES, OIL MEANS AN AUTO BODY SHOPIS NEARBY."
2770 H$(31) = "THE BUG WILL NOT BOTHER YOU. IT IS ASLEEP. HINT: IF YOU LINGER TOO LONG IN THIS ROOM, IT WILL WAKE UP!"
2780 H$(2) = "YOU KNOW, IN THIS ENCHANTED WORLD, MANY THINGS THAT ARE SMALL ON EARTH ARE VERY LARGE..."
2790 H$(20) = "TRY TO FIND YOUR WAY TO THE OTHER END, DUMMY!!!":H$(23) = H$(20)
2800 RETURN